Všeobecný vzorec
=OR($B5=LOOKUP(width,widths),B$5=LOOKUP(height,heights))
Zhrnutie
Ak chcete zvýrazniť riadky a stĺpce spojené s približnou zhodou, môžete použiť podmienené formátovanie pomocou vzorca založeného na funkcii LOOKUP spolu s logickou funkciou ako OR alebo AND. V zobrazenom príklade je vzorec použitý na použitie podmieneného formátovania:
=OR($B5=LOOKUP(width,widths),B$5=LOOKUP(height,heights))
Vysvetlenie
Tento vzorec používa 4 pomenované rozsahy definované takto:
width=K6 widths=B6:B11 heights=C5:H5
Podmienené formátovanie sa vyhodnotí vzhľadom na každú bunku, na ktorú sa použije, počnúc aktívnou bunkou vo výbere, ktorou je v tomto prípade bunka B5. Na zvýraznenie zodpovedajúceho riadku použijeme tento logický výraz:
$B5=LOOKUP(width,widths)
Odkaz na B5 je zmiešaný, pričom stĺpec je uzamknutý a riadok odomknutý, takže iba hodnoty v stĺpci B (šírky) sa porovnajú s hodnotami v K6 (šírka). V zobrazenom príklade vráti tento logický výraz hodnotu TRUE pre každú bunku v riadku, kde je šírka 200, na základe približnej zhody hodnoty v K6 (šírka, 275) so všetkými hodnotami v K6: B11 (šírky). To sa deje pomocou funkcie LOOKUP:
LOOKUP(width,widths)
Rovnako ako funkcia MATCH, aj funkcia LOOKUP bude prechádzať zoradenými hodnotami, kým sa nenájde väčšia hodnota, potom sa vráti o krok späť k predchádzajúcej hodnote, ktorá je v tomto prípade 200.
Na zvýraznenie zodpovedajúceho stĺpca používame tento logický výraz:
B$5=LOOKUP(height,heights)
Odkaz na B5 je zmiešaný so stĺpcom relatívny a riadok absolútny, takže iba hodnoty v riadku 5 (výšky) sa porovnávajú s hodnotami v K7 (výška). V zobrazenom príklade vráti tento logický výraz hodnotu TRUE pre každú bunku v rade, kde je výška 300, na základe približnej zhody hodnoty v K7 (výška, 325) so všetkými hodnotami v C5: H5 (výšky). To sa deje pomocou funkcie LOOKUP:
LOOKUP(height,heights)
Ako je uvedené vyššie, VYHĽADÁVANIE bude prebiehať cez zoradené hodnoty, kým sa nenájde väčšia hodnota, potom sa vráti o krok späť k predchádzajúcej hodnote, ktorá je v tomto prípade 300.
Zvýraznite iba križovatku
Ak chcete zvýrazniť iba križovatku, stačí nahradiť funkciu OR funkciou AND:
=AND($B5=LOOKUP(width,widths),B$5=LOOKUP(height,heights))
